//---------------------------------------------------------------
// Fichero:  ejemplo3.asy
// Objetivo: Representación del ejemplo 3
// Fecha:    V.12.6.2026
// Autor:    Pedro Reina
// Licencia: CC0 1.0 Universal
//           http://creativecommons.org/publicdomain/zero/1.0/
//---------------------------------------------------------------

// fontsize()
import fontsize;

// graph(), xaxis(), yaxis()
import graph;

// Obtendremos un archivo SVG
settings.outformat="svg";

// Tamaño de la imagen
size(8.8cm);

// Dimensiones de los ejes
real Xmin = -12, Xmax = 12, Ymin = -2, Ymax = 2, Extra = 0.25;

// Grosor de las líneas
defaultpen(1);

// Formato de marcas de los dos ejes
ticks FormatoTicks = Ticks(Step=1, NoZero, Size=0.5mm, pTick=blue);

// Formato de texto de los dos ejes
pen FormatoTexto = blue+fontsize(4pt);

// El eje de ordenadas
yaxis(ymin=Ymin, ymax=Ymax, FormatoTexto, FormatoTicks);
draw((0,Ymin-Extra) -- (0,Ymax+Extra), gray);

// El eje de abscisas
xaxis(xmin=Xmin, xmax=Xmax, FormatoTexto, FormatoTicks);
draw((Xmin-Extra,0) -- (Xmax+Extra,0), gray);

// La gráfica
real F(real x)
    { return (-1.40*sin(pi*x)+0.75*cos(2*pi*x)+0.20*cos(4*pi*x)+0.5); }
path Grafica=graph(F,0,2,n=100);
pen Color;
for ( int i=0 ; i<12 ; ++i )
    {
    if ((int)(i/2)%2 == 0) Color = deepgreen; else Color = red;
    draw(shift(2*(i-6),0)*Grafica,1.25bp+Color);
    }