//---------------------------------------------------------------
// Fichero:  solucion02.asy
// Objetivo: Dar la solución del ejercicio 2
// Fecha:    X.17.6.2026
// Autor:    Pedro Reina
// Licencia: CC0 1.0 Universal
//           http://creativecommons.org/publicdomain/zero/1.0/
//---------------------------------------------------------------

// Obtendremos un archivo SVG
settings.outformat="svg";

// El valor que hay que representar
real a=0.73;

// Tamaño de la imagen
size(3cm);

// Grosor de las líneas
defaultpen(1);

// El tamaño de los semiejes
real Tam=1.1, Extra=0.75;

// Los ejes de coordenadas
draw ((-Tam,0) -- (Tam,0));
draw ((0,-Tam) -- (0,Tam+Extra));

// La circunferencia
draw(unitcircle,deepgreen);

// La recta paralela al eje de ordenadas
draw ((a,-Tam) -- (a,Tam),1.25bp+gray);

// El ángulo
real Alfa=aCos(a);

// Calculamos el punto que representa al ángulo
pair P=dir(Alfa);

// La semirrecta origen
draw((0,0) -- (Tam,0), 1.25bp+blue);

// La otra semirrecta
draw((0,0) -- Tam*P, 1.25bp+blue);

// El punto del eje de abscisas
dot((a,0),3bp+red);

// Representamos el punto que representa al ángulo
dot(P, 3bp+red);
dot(P, 2bp+white);

// El arco con flecha
draw(arc((0,0),0.5,0,Alfa),orange,ArcArrow(SimpleHead,1mm));